mkstemp.m4 2.54 KB
Newer Older
1
#serial 20
2

3
# Copyright (C) 2001, 2003-2007, 2009-2011 Free Software Foundation, Inc.
4 5 6 7 8 9 10 11 12
# This file is free software; the Free Software Foundation
# gives unlimited permission to copy and/or distribute it,
# with or without modifications, as long as this notice is preserved.

# On some hosts (e.g., HP-UX 10.20, SunOS 4.1.4, Solaris 2.5.1), mkstemp has a
# silly limit that it can create no more than 26 files from a given template.
# Other systems lack mkstemp altogether.
# On OSF1/Tru64 V4.0F, the system-provided mkstemp function can create
# only 32 files per process.
13 14
# On some hosts, mkstemp creates files with mode 0666, which is a security
# problem and a violation of POSIX 2008.
15 16 17 18 19 20 21 22 23 24 25 26 27 28 29
# On systems like the above, arrange to use the replacement function.
AC_DEFUN([gl_FUNC_MKSTEMP],
[
  AC_REQUIRE([gl_STDLIB_H_DEFAULTS])
  AC_REQUIRE([AC_SYS_LARGEFILE])

  AC_CHECK_FUNCS_ONCE([mkstemp])
  if test $ac_cv_func_mkstemp = yes; then
    AC_CACHE_CHECK([for working mkstemp],
      [gl_cv_func_working_mkstemp],
      [
        mkdir conftest.mkstemp
        AC_RUN_IFELSE(
          [AC_LANG_PROGRAM(
            [AC_INCLUDES_DEFAULT],
30 31
            [[int result = 0;
              int i;
32 33 34
              off_t large = (off_t) 4294967295u;
              if (large < 0)
                large = 2147483647;
35
              umask (0);
36 37 38 39 40
              for (i = 0; i < 70; i++)
                {
                  char templ[] = "conftest.mkstemp/coXXXXXX";
                  int (*mkstemp_function) (char *) = mkstemp;
                  int fd = mkstemp_function (templ);
41 42 43 44 45 46 47 48 49 50 51 52 53 54
                  if (fd < 0)
                    result |= 1;
                  else
                    {
                      struct stat st;
                      if (lseek (fd, large, SEEK_SET) != large)
                        result |= 2;
                      if (fstat (fd, &st) < 0)
                        result |= 4;
                      else if (st.st_mode & 0077)
                        result |= 8;
                      if (close (fd))
                        result |= 16;
                    }
55
                }
56
              return result;]])],
57 58
          [gl_cv_func_working_mkstemp=yes],
          [gl_cv_func_working_mkstemp=no],
59
          [gl_cv_func_working_mkstemp="guessing no"])
60 61
        rm -rf conftest.mkstemp
      ])
62
    if test "$gl_cv_func_working_mkstemp" != yes; then
63 64 65 66 67 68 69 70 71 72 73 74 75 76 77
      REPLACE_MKSTEMP=1
      AC_LIBOBJ([mkstemp])
      gl_PREREQ_MKSTEMP
    fi
  else
    HAVE_MKSTEMP=0
    AC_LIBOBJ([mkstemp])
    gl_PREREQ_MKSTEMP
  fi
])

# Prerequisites of lib/mkstemp.c.
AC_DEFUN([gl_PREREQ_MKSTEMP],
[
])