ptsname_r.m4 2.9 KB
Newer Older
1
# ptsname_r.m4 serial 5
2
dnl Copyright (C) 2010-2018 Free Software Foundation, Inc.
Eric Blake's avatar
Eric Blake committed
3 4 5 6 7 8 9 10 11 12 13 14 15 16
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.

AC_DEFUN([gl_FUNC_PTSNAME_R],
[
  AC_REQUIRE([gl_UNISTD_H_DEFAULTS])

  dnl Persuade glibc <stdlib.h> to declare ptsname_r().
  AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])

  AC_CHECK_FUNCS_ONCE([ptsname_r])
  if test $ac_cv_func_ptsname_r = no; then
    HAVE_PTSNAME_R=0
17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43
  else
    dnl On OSF/1 5.1, the type of the third argument is 'int', not 'size_t',
    dnl and the declaration is missing if _REENTRANT is not defined.
    AC_CACHE_CHECK([whether ptsname_r has the same signature as in glibc],
      [gl_cv_func_ptsname_r_signature_ok],
      [AC_COMPILE_IFELSE(
         [AC_LANG_PROGRAM(
            [[#include <stddef.h>
              #include <stdlib.h>
              /* Test whether ptsname_r is declared at all.  */
              int (*f) (int, char *, size_t) = ptsname_r;
              /* Test whether it has the same declaration as in glibc.  */
              #undef ptsname_r
              extern
              #ifdef __cplusplus
              "C"
              #endif
              int ptsname_r (int, char *, size_t);
            ]],
            [[return f (0, NULL, 0);]])
         ],
         [gl_cv_func_ptsname_r_signature_ok=yes],
         [gl_cv_func_ptsname_r_signature_ok=no])
      ])
    if test $gl_cv_func_ptsname_r_signature_ok = no; then
      REPLACE_PTSNAME_R=1
    fi
Eric Blake's avatar
Eric Blake committed
44
  fi
45 46

  AC_REQUIRE([AC_HEADER_MAJOR])
Eric Blake's avatar
Eric Blake committed
47 48 49 50
])

# Prerequisites of lib/ptsname.c.
AC_DEFUN([gl_PREREQ_PTSNAME_R], [
51 52 53 54 55 56
  AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  AC_CACHE_CHECK([whether isatty sets errno when it fails],
    [gl_cv_func_isatty_sets_errno],
    [AC_RUN_IFELSE(
       [AC_LANG_PROGRAM(
          [[#include <errno.h>
57
            #if defined _WIN32 && ! defined __CYGWIN__
58 59 60 61 62 63 64 65 66 67 68 69 70
            # include <io.h>
            #else
            # include <unistd.h>
            #endif
          ]],
          [[errno = 0;
            isatty (-1);
            return errno == 0;
          ]])
       ],
       [gl_cv_func_isatty_sets_errno=yes],
       [gl_cv_func_isatty_sets_errno=no],
       [case "$host_os" in
71 72 73 74 75 76 77 78 79 80 81
          irix* | solaris*)
            gl_cv_func_isatty_sets_errno="guessing no" ;;
          mingw*) # Guess yes on mingw, no on MSVC.
            AC_EGREP_CPP([Known], [
#ifdef __MINGW32__
 Known
#endif
              ],
              [gl_cv_func_isatty_sets_errno="guessing yes"],
              [gl_cv_func_isatty_sets_errno="guessing no"])
            ;;
82
          *)
83
            gl_cv_func_isatty_sets_errno="guessing yes" ;;
84 85 86 87 88 89 90 91 92 93
        esac
       ])
    ])
  case "$gl_cv_func_isatty_sets_errno" in
    *yes) ;;
    *)
      AC_DEFINE([ISATTY_FAILS_WITHOUT_SETTING_ERRNO], [1],
        [Define to 1 if isatty() may fail without setting errno.])
      ;;
  esac
Eric Blake's avatar
Eric Blake committed
94
])